ArcGIS Add Dynamic Data
ArcGIS_AddDynamicData_VBNet\ChangeRenderer_ADF.aspx.vb
' Copyright 2009 ESRI
' 
' All rights reserved under the copyright laws of the United States
' and applicable international laws, treaties, and conventions.
' 
' You may freely redistribute and use this sample code, with or
' without modification, provided you include the original copyright
' notice and use restrictions.
' 
' See the use restrictions.
' 

' Illustrates how to change the renderers of existing layers in a pooled ArcGIS Server map service
' using Web ADF controls and ArcObjects.  The layers are modified in a shallowly stateful way, meaning
' that the changes persist in the user's browser, but do not affect the appearance of the map service
' when viewed by other clients.

Imports Microsoft.VisualBasic
Imports System
Public Partial Class ChangeRenderer_ADF
  Inherits System.Web.UI.Page
  Implements System.Web.UI.ICallbackEventHandler
  #Region "Instance Variable Declarations"

  Private m_adfCallbackFunctionString As String
  Private m_callbackResultCollection As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResultCollection = New ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResultCollection()
  Private m_serverObjectStateModifier As ServerObjectStateModifier = Nothing

  #End Region

  #Region "ASP.NET Page Life Cycle Event Handlers"

  Public Sub Page_PreInit(ByVal sender As Object, ByVal eventArgs As System.EventArgs)
    ' Instantiate a ServerObjectStateModifier object to use for adding and removing the dynamic layer
    m_serverObjectStateModifier = New ServerObjectStateModifier()
  End Sub

  Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs)
    Try
      ' Define the parameters for a browser call to the WebForm_DoCallback JavaScript function
      ' via the GetCallbackEventReference function.  The GetCallbackEventReference function returns 
      ' the syntax for initiating a callback (i.e a call to WebForm_DoCallback) with the passed-in 
      ' parameters.  Here the parameters are defined as follows:
      ' this - the Page will handle the callback request
      ' "message" - a JavaScript variable named "message" will contain argument-value pairs passed 
      '      to the callback server-side
      ' "processCallbackResult" - name of the JavaScript function to process the callback 
      '      results from the server.  This function is the callback results handler included with 
      '      the Web ADF JavaScript Library.
      ' "context" - a JavaScript variable named "context" which can be used by the client to
      '      indicate the origin of the callback
      ' "postBackError" - name of the JavaScript function that will process errors returned during 
      '      callback processing.  This is the callback error handler included with the Web ADF 
      '      JavaScript Library
      ' true - define whether the callback is synchronous or asynchronous.  True is asynchronous.        
      m_adfCallbackFunctionString = Page.ClientScript.GetCallbackEventReference(Me, "message", "processCallbackResult", "context", "postBackError", True)

      ' If the renderers have been changed (indicated by the session variable), then we need to re-apply them
      ' so that the Web ADF components accessing the changed map resources are aware of the change.  
      If (Not Session("RendererChanged") Is Nothing) AndAlso CBool(Session("RendererChanged")) Then
        ChangeRenderers(ServerObjectStateModifier.RendererAction.ApplyLast)
      End If

      AddHandler MapResourceManager1.ResourcesDispose, AddressOf MapResourceManager1_ResourcesDispose
    Catch exception As System.Exception
      ' Check whether the page is loading as a result of a callback.  If not, assume that a full page postback
      ' is occuring, since this page implements the callback framework (and not partial postback).
      If Page.IsCallback Then
        ' Get a callback result that will show an alert with information pertaining to the exception
        Dim errorCallbackResult As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResult = Utility.GetErrorCallback(exception)
        ' Get the control that initiated the postback
        Dim control As System.Web.UI.Control = Utility.GetPostBackControl(Page)

        ' If the control is a Web ADF Control (i.e. WebCotnrol or CompositeControl), add the error 
        ' callback to that control's callback results.  Otherwise, add the error callback to the 
        ' callback results collection member variable, which will be passed to the client in 
        ' GetCallbackResult.
        If TypeOf control Is ESRI.ArcGIS.ADF.Web.UI.WebControls.WebControl Then
          Dim adfWebControl As ESRI.ArcGIS.ADF.Web.UI.WebControls.WebControl = TryCast(control, ESRI.ArcGIS.ADF.Web.UI.WebControls.WebControl)
          adfWebControl.CallbackResults.Add(errorCallbackResult)
        ElseIf TypeOf control Is ESRI.ArcGIS.ADF.Web.UI.WebControls.CompositeControl Then
          Dim adfCompositeControl As ESRI.ArcGIS.ADF.Web.UI.WebControls.CompositeControl = TryCast(control, ESRI.ArcGIS.ADF.Web.UI.WebControls.CompositeControl)
          adfCompositeControl.CallbackResults.Add(errorCallbackResult)
        Else
          m_callbackResultCollection.Add(errorCallbackResult)
        End If
      Else
        ' Since the page is in full postback, write the javascript alert code directly to the response
        Dim jsErrorAlert As String = String.Format("<script>{0}</script>", Utility.GetJavaScriptErrorString(exception))
        Response.Write(jsErrorAlert)
      End If
    End Try
  End Sub

  #End Region

  #Region "Web ADF Control Event Handlers"

  ' If the resources' renderers have been changed (indicated by the session variable), then we need to restore them to 
  ' their original state before the server context created as a result of the current page request is released.  
  ' Otherwise, the altered renderers will be applied to the map service outside the scope of this request, meaning they 
  ' will be seen by other clients using the service.
  Private Sub MapResourceManager1_ResourcesDispose(ByVal sender As Object, ByVal e As System.EventArgs)
    If (Not Session("RendererChanged") Is Nothing) AndAlso CBool(Session("RendererChanged")) Then
      ChangeRenderers(ServerObjectStateModifier.RendererAction.ApplyOriginal)
    End If
  End Sub

  #End Region

  #Region "ICallbackEventHandler Members"

  ' Receives the arguments packaged in the callback on the client.  We parse those arguments here and 
  ' initiate server-side logic accordingly.
  Public Sub RaiseCallbackEvent(ByVal eventArgs As String) Implements System.Web.UI.ICallbackEventHandler.RaiseCallbackEvent
    Try
      ' Parse the callback string passed from the client to the server into separate
      ' arguments using the Web ADF's callback parsing utility.
      Dim callbackArgsCollection As System.Collections.Specialized.NameValueCollection = ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackUtility.ParseStringIntoNameValueCollection(eventArgs)

      ' Check whether the callback event argument specifies changing or resetting the renderers and take
      ' action accordingly
      Select Case callbackArgsCollection("EventArg")
        Case "ChangeRenderers"
          ChangeRenderers(ServerObjectStateModifier.RendererAction.ApplyNew)
          RefreshResourcesAndToc()

          ' Set the session variable indicating that renderers for the resources in the map have been changed.  
          ' We do this to share this information with the custom map handler.
          Session("RendererChanged") = True
        Case "ResetRenderers"
          ChangeRenderers(ServerObjectStateModifier.RendererAction.ApplyOriginal)
          RefreshResourcesAndToc()

          ' Set the session variables indicating that renderers for the resources in the map are in their  
          ' original state.  We do this to share this information with the custom map handler.
          Session("RendererChanged") = False
      End Select
    Catch exception As System.Exception
      ' Get a callback result that will alert the user of the error and add it to the callback results collection
      Dim errorCallbackResult As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResult = Utility.GetErrorCallback(exception)
      m_callbackResultCollection.Add(errorCallbackResult)
    End Try
  End Sub

  ' The last server-side method called before the callback returns to the browser, GetCallbackResult
  ' is where the server-side result of the callback is passed back to the browser as a string for
  ' processing by the client.
  Public Function GetCallbackResult() As String Implements System.Web.UI.ICallbackEventHandler.GetCallbackResult
    ' Return the string representation of the instance variable containing the callback results
    Return m_callbackResultCollection.ToString()
  End Function

  #End Region

  #Region "Instance Properties"

  ' Property allowing client-side access to the client callback function string.  This string
  ' contains the necessary JavaScript syntax to initiate a callback with the parameters specified
  ' in GetCallbackEventReference (in Page_Load).
  Public Property AdfCallbackFunctionString() As String
    Get
      Return m_adfCallbackFunctionString
    End Get
    Set
      m_adfCallbackFunctionString = Value
    End Set
  End Property

  #End Region

  #Region "Instance Methods"

  ' Refreshes the Toc and all the resources in the Map
  Private Sub RefreshResourcesAndToc()
    For Each mapResourceItem As ESRI.ArcGIS.ADF.Web.UI.WebControls.MapResourceItem In MapResourceManager1.ResourceItems
      Map1.RefreshResource(mapResourceItem.Name)
    Next mapResourceItem

    Toc1.Refresh()
    Map1.CallbackResults.CopyFrom(Toc1.CallbackResults)

    m_callbackResultCollection.CopyFrom(Map1.CallbackResults)
  End Sub

  ' Makes sure each resource in the map is initialized, then uses the ServerObjectStateModifier to apply random simple 
  ' renderers to its layers
  Private Sub ChangeRenderers(ByVal rendererAction As ServerObjectStateModifier.RendererAction)
    For Each mapResourceItem As ESRI.ArcGIS.ADF.Web.UI.WebControls.MapResourceItem In MapResourceManager1.ResourceItems
      If TypeOf mapResourceItem.Resource Is ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal Then
        If (Not mapResourceItem.Resource.Initialized) Then
          mapResourceItem.InitializeResource()
        End If

        m_serverObjectStateModifier.ApplySimpleRenderers(TryCast(mapResourceItem.Resource, ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal), rendererAction)
      End If
    Next mapResourceItem
  End Sub

  #End Region
End Class