ArcGIS Add Dynamic Data
ArcGIS_AddDynamicData_VBNet\Default_ADF.aspx.vb
' Copyright 2009 ESRI
' 
' All rights reserved under the copyright laws of the United States
' and applicable international laws, treaties, and conventions.
' 
' You may freely redistribute and use this sample code, with or
' without modification, provided you include the original copyright
' notice and use restrictions.
' 
' See the use restrictions.
' 

' Illustrates how to add a new layer dynamically to a pooled ArcGIS Server map service using Web ADF controls and ArcObjects.
' Functionally identical to CustomMapHandler_ADF, but bypasses the custom map handler by having the map's EnableMapHandler
' property set to false.

Imports Microsoft.VisualBasic
Imports System
Public Partial Class Default_ADF
  Inherits System.Web.UI.Page
  Implements System.Web.UI.ICallbackEventHandler
  #Region "Instance Variable Declarations"

  Private m_adfCallbackFunctionString As String
  Private m_callbackResultCollection As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResultCollection = New ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResultCollection()
  Private m_serverObjectStateModifier As ServerObjectStateModifier = Nothing

  ' Specify the name of the resource to target when adding/removing the dynamic layer
  Private m_targetResourceName As String = "MapResourceItem0"
  ' Specify the name of the layer to be added/removed
  Private m_dynamicLayerName As String = "Canada"

  #End Region

  #Region "ASP.NET Page Life Cycle Event Handlers"

  Public Sub Page_PreInit(ByVal sender As Object, ByVal eventArgs As System.EventArgs)
    ' Instantiate a ServerObjectStateModifier object to use for adding and removing the dynamic layer
    m_serverObjectStateModifier = New ServerObjectStateModifier()
  End Sub

  Protected Sub Page_Load(ByVal sender As Object, ByVal eventArgs As System.EventArgs)
    Try
      ' Define the parameters for a browser call to the WebForm_DoCallback JavaScript function
      ' via the GetCallbackEventReference function.  The GetCallbackEventReference function returns 
      ' the syntax for initiating a callback (i.e a call to WebForm_DoCallback) with the passed-in 
      ' parameters.  Here the parameters are defined as follows:
      ' this - the Page will handle the callback request
      ' "message" - a JavaScript variable named "message" will contain argument-value pairs passed 
      '      to the callback server-side
      ' "processCallbackResult" - name of the JavaScript function to process the callback 
      '      results from the server.  This function is the callback results handler included with 
      '      the Web ADF JavaScript Library.
      ' "context" - a JavaScript variable named "context" which can be used by the client to
      '      indicate the origin of the callback
      ' "postBackError" - name of the JavaScript function that will process errors returned during 
      '      callback processing.  This is the callback error handler included with the Web ADF 
      '      JavaScript Library
      ' true - define whether the callback is synchronous or asynchronous.  True is asynchronous.        
      m_adfCallbackFunctionString = Page.ClientScript.GetCallbackEventReference(Me, "message", "processCallbackResult", "context", "postBackError", True)

      ' Store the name of the resource to target for dynamic layer addition/removal in session.  We do this to share
      ' this information with the custom map handler
      Session("targetResourceName") = m_targetResourceName

      ' If the dynamic layer is currently present (indicated by the session variable), then we need to re-add it so that
      ' the Web ADF components accessing the map resource containing that layer are aware of its presence.  
      If (Not Session("dynamicLayerAdded") Is Nothing) AndAlso (CBool(Session("dynamicLayerAdded"))) Then
        ' Get the dynamic layer's target resource and call the method to add the dynamic layer to it
        Dim agsMapFunctionality As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality = CType(Map1.GetFunctionality(m_targetResourceName), ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality)
        Dim mapResourceLocal As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal = CType(agsMapFunctionality.Resource, ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal)
        m_serverObjectStateModifier.AddLayer(mapResourceLocal, m_dynamicLayerName)
      End If

      AddHandler MapResourceManager1.ResourcesDispose, AddressOf MapResourceManager1_ResourcesDispose
    Catch exception As System.Exception
      ' Check whether the page is loading as a result of a callback.  If not, assume that a full page postback
      ' is occuring, since this page implements the callback framework (and not partial postback).
      If Page.IsCallback Then
        ' Get a callback result that will show an alert with information pertaining to the exception
        Dim errorCallbackResult As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResult = Utility.GetErrorCallback(exception)
        ' Get the control that initiated the postback
        Dim control As System.Web.UI.Control = Utility.GetPostBackControl(Page)

        ' If the control is a Web ADF Control (i.e. WebCotnrol or CompositeControl), add the error 
        ' callback to that control's callback results.  Otherwise, add the error callback to the 
        ' callback results collection member variable, which will be passed to the client in 
        ' GetCallbackResult.
        If TypeOf control Is ESRI.ArcGIS.ADF.Web.UI.WebControls.WebControl Then
          Dim adfWebControl As ESRI.ArcGIS.ADF.Web.UI.WebControls.WebControl = TryCast(control, ESRI.ArcGIS.ADF.Web.UI.WebControls.WebControl)
          adfWebControl.CallbackResults.Add(errorCallbackResult)
        ElseIf TypeOf control Is ESRI.ArcGIS.ADF.Web.UI.WebControls.CompositeControl Then
          Dim adfCompositeControl As ESRI.ArcGIS.ADF.Web.UI.WebControls.CompositeControl = TryCast(control, ESRI.ArcGIS.ADF.Web.UI.WebControls.CompositeControl)
          adfCompositeControl.CallbackResults.Add(errorCallbackResult)
        Else
          m_callbackResultCollection.Add(errorCallbackResult)
        End If
      Else
        ' Since the page is in full postback, write the javascript alert code directly to the response
        Dim jsErrorAlert As String = String.Format("<script>{0}</script>", Utility.GetJavaScriptErrorString(exception))
        Response.Write(jsErrorAlert)
      End If
    End Try
  End Sub

  #End Region

  #Region "Web ADF Control Event Handlers"

  Private Sub MapResourceManager1_ResourcesDispose(ByVal sender As Object, ByVal e As System.EventArgs)
    ' If the dynamic layer is currently present (indicated by the session variable), then we need to remove it from the
    ' map service before the server context created as a result of the current page request is released.  Otherwise, 
    ' the layer will remain in the map service outside the scope of this request, making it possible for this layer to 
    ' be seen by other clients.
    If (Not Session("dynamicLayerAdded") Is Nothing) AndAlso (CBool(Session("dynamicLayerAdded"))) Then
      ' Get the dynamic layer's target resource and call the method to remove the dynamic layer from it
      Dim agsMapFunctionality As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality = CType(Map1.GetFunctionality(m_targetResourceName), ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality)
      Dim mapResourceLocal As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal = CType(agsMapFunctionality.Resource, ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal)
      m_serverObjectStateModifier.RemoveLayer(mapResourceLocal, m_dynamicLayerName)
    End If
  End Sub

  Protected Sub Toc1_NodeChecked(ByVal sender As Object, ByVal treeViewPlusNodeArgs As ESRI.ArcGIS.ADF.Web.UI.WebControls.TreeViewPlusNodeEventArgs)
    Try
      Dim treeViewPlusNode As ESRI.ArcGIS.ADF.Web.UI.WebControls.TreeViewPlusNode = treeViewPlusNodeArgs.Node
      Dim tocLayer As ESRI.ArcGIS.ADF.Web.TocLayer = TryCast(treeViewPlusNode.Data, ESRI.ArcGIS.ADF.Web.TocLayer)

      If tocLayer Is Nothing Then
      Return
      End If

      ' If the dynamic layer was clicked, change it's visibility in the Toc and store its new visibility in session.  
      ' We do this so that the proper visibility can be applied if the layer is removed and re-added.
      If tocLayer.Name = m_dynamicLayerName Then
        tocLayer.Visible = Not tocLayer.Visible
        Session("dynamicLayerVisible") = tocLayer.Visible
      End If
    Catch exception As System.Exception
      ' Get a callback that will show an alert containing information about the error and add it to the Toc's
      ' callback results
      Dim errorCallbackResult As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResult = Utility.GetErrorCallback(exception)
      Toc1.CallbackResults.Add(errorCallbackResult)
    End Try
  End Sub

  #End Region

  #Region "ICallbackEventHandler Members"

  ' Receives the arguments packaged in the callback on the client.  We parse those arguments here and 
  ' initiate server-side logic accordingly.
  Public Sub RaiseCallbackEvent(ByVal eventArgs As String) Implements System.Web.UI.ICallbackEventHandler.RaiseCallbackEvent
    Try
      Dim agsMapFunctionality As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality = CType(Map1.GetFunctionality(m_targetResourceName), ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality)
      Dim mapResourceLocal As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal = CType(agsMapFunctionality.Resource, ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal)

      ' Parse the callback string passed from the client to the server into separate        
      ' arguments using the Web ADF's callback parsing utility.
      Dim callbackArgsCollection As System.Collections.Specialized.NameValueCollection = ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackUtility.ParseStringIntoNameValueCollection(eventArgs)

      ' Check whether the callback event argument specifies adding or removing layers
      Select Case callbackArgsCollection("EventArg")
        Case "addLayer"
          ' Set session variables indicating the presence and name of the dynamic layer.  We do this to share
          ' this information across page requests.
          Session("dynamicLayerAdded") = True

          ' Call the method to add the dynamic layer, which will add the layer to the map service.
          m_serverObjectStateModifier.AddLayer(mapResourceLocal, m_dynamicLayerName)

          ' Refresh the Map and Toc controls so they show the layer.
          RefreshMapAndToc()
        Case "removeLayer"
          ' Set the session variable indicating the absence of the dynamic layer
          Session("dynamicLayerAdded") = False

          ' Call the method to remove the dynamic layer, which will remove the layer from the map service.
          m_serverObjectStateModifier.RemoveLayer(mapResourceLocal, m_dynamicLayerName)

          ' Refresh the Map and Toc controls so they do not show the layer.
          RefreshMapAndToc()
      End Select
    Catch exception As System.Exception
      ' Get a callback result that will alert the user of the error and add it to the callback results collection
      Dim errorCallbackResult As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResult = Utility.GetErrorCallback(exception)
      m_callbackResultCollection.Add(errorCallbackResult)
    End Try
  End Sub

  ' Last server-side method called before the callback returns to the browser.  Here we specify the 
  ' the server-side result of the callback (as a string) to be passed back to the browser.
  Public Function GetCallbackResult() As String Implements System.Web.UI.ICallbackEventHandler.GetCallbackResult
    Return m_callbackResultCollection.ToString()
  End Function

  #End Region

  #Region "Instance Properties"

  ' Store the callback function string used by the browser to initiate a callback request.
  ' Added to the aspx page as a server variable - populated at runtime.
  Public Property AdfCallbackFunctionString() As String
    Get
      Return m_adfCallbackFunctionString
    End Get
    Set
      m_adfCallbackFunctionString = Value
    End Set
  End Property

  #End Region

  #Region "Instance Methods"

  ' Refreshes the Map and Toc controls and populates the callback results member variable with the
  ' resulting callback results 
  Public Sub RefreshMapAndToc()
    Toc1.Refresh()
    Map1.CallbackResults.CopyFrom(Toc1.CallbackResults)

    Map1.RefreshResource(m_targetResourceName)
    m_callbackResultCollection.CopyFrom(Map1.CallbackResults)
  End Sub

  #End Region
End Class