ArcGIS Add Dynamic Data
ArcGIS_AddDynamicData_VBNet\RemoveLayer_ADF.aspx.vb
' Copyright 2009 ESRI
' 
' All rights reserved under the copyright laws of the United States
' and applicable international laws, treaties, and conventions.
' 
' You may freely redistribute and use this sample code, with or
' without modification, provided you include the original copyright
' notice and use restrictions.
' 
' See the use restrictions.
' 

' Illustrates how to remove an existing layer in a pooled ArcGIS Server map service using Web ADF components
' and ArcObjects. For illustration of how to add and remove a dynamic layer from a map service, see the 
' Default_ADF and CustomMapHandler_ADF pages. Note that this code bypasses use of the custom map handler (and
' the accompanying increase in map performance) by setting the Map1.EnableMapHandler property to false.

Imports Microsoft.VisualBasic
Imports System
Public Partial Class RemoveLayer_ADF
  Inherits System.Web.UI.Page
  Implements System.Web.UI.ICallbackEventHandler
  #Region "Instance Variable Declarations"

  Private m_adfCallbackFunctionString As String
  Private m_callbackResultCollection As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResultCollection = New ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResultCollection()
  Private m_serverObjectStateModifier As ServerObjectStateModifier = Nothing
  Private m_removedLayerDictionary As System.Collections.Generic.Dictionary(Of Integer, ESRI.ArcGIS.Carto.ILayer) = Nothing

  ' Specify the name of the resource containing the layer to remove
  Private m_targetResourceName As String = "MapResourceItem0"
  ' Specify the name of the layer to remove
  Private m_targetLayerName As String = "Highways"

  #End Region

  #Region "ASP.NET Page Life Cycle Event Handlers"

  Protected Sub Page_PreInit(ByVal sender As Object, ByVal e As System.EventArgs)
    ' Instantiate a class-level ServerObjectStateModifier to use in removing and re-adding the layer
    m_serverObjectStateModifier = New ServerObjectStateModifier()
  End Sub

  Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs)
    Try
      ' Define the parameters for a browser call to the WebForm_DoCallback JavaScript function
      ' via the GetCallbackEventReference function.  The GetCallbackEventReference function returns 
      ' the syntax for initiating a callback (i.e a call to WebForm_DoCallback) with the passed-in 
      ' parameters.  Here the parameters are defined as follows:
      ' this - the Page will handle the callback request
      ' "message" - a JavaScript variable named "message" will contain argument-value pairs passed 
      '      to the callback server-side
      ' "processCallbackResult" - name of the JavaScript function to process the callback 
      '      results from the server.  This function is the callback results handler included with 
      '      the Web ADF JavaScript Library.
      ' "context" - a JavaScript variable named "context" which can be used by the client to
      '      indicate the origin of the callback
      ' "postBackError" - name of the JavaScript function that will process errors returned during 
      '      callback processing.  This is the callback error handler included with the Web ADF 
      '      JavaScript Library
      ' true - define whether the callback is synchronous or asynchronous.  True is asynchronous.        
      m_adfCallbackFunctionString = Page.ClientScript.GetCallbackEventReference(Me, "message", "processCallbackResult", "context", "postBackError", True)

      ' If the target layer has been removed (indicated by the session variable), then we need to re-remove it
      ' so that the Web ADF components accessing the changed map resource is aware of the change.  
      If (Not Session("LayerRemoved") Is Nothing) AndAlso (CBool(Session("LayerRemoved"))) Then
        ' Get the layer's target resource and call the method to remove the layer from it
        Dim agsMapFunctionality As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality = CType(Map1.GetFunctionality(m_targetResourceName), ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality)
        Dim mapResourceLocal As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal = CType(agsMapFunctionality.Resource, ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal)
        m_removedLayerDictionary = m_serverObjectStateModifier.RemoveLayer(mapResourceLocal, m_targetLayerName)
      End If

      AddHandler MapResourceManager1.ResourcesDispose, AddressOf MapResourceManager1_ResourcesDispose
    Catch exception As System.Exception
      ' Check whether the page is loading as a result of a callback.  If not, assume that a full page postback
      ' is occuring, since this page implements the callback framework (and not partial postback).
      If Page.IsCallback Then
        ' Get a callback result that will show an alert with information pertaining to the exception
        Dim errorCallbackResult As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResult = Utility.GetErrorCallback(exception)
        ' Get the control that initiated the postback
        Dim control As System.Web.UI.Control = Utility.GetPostBackControl(Page)

        ' If the control is a Web ADF Control (i.e. WebCotnrol or CompositeControl), add the error 
        ' callback to that control's callback results.  Otherwise, add the error callback to the 
        ' callback results collection member variable, which will be passed to the client in 
        ' GetCallbackResult.
        If TypeOf control Is ESRI.ArcGIS.ADF.Web.UI.WebControls.WebControl Then
          Dim adfWebControl As ESRI.ArcGIS.ADF.Web.UI.WebControls.WebControl = TryCast(control, ESRI.ArcGIS.ADF.Web.UI.WebControls.WebControl)
          adfWebControl.CallbackResults.Add(errorCallbackResult)
        ElseIf TypeOf control Is ESRI.ArcGIS.ADF.Web.UI.WebControls.CompositeControl Then
          Dim adfCompositeControl As ESRI.ArcGIS.ADF.Web.UI.WebControls.CompositeControl = TryCast(control, ESRI.ArcGIS.ADF.Web.UI.WebControls.CompositeControl)
          adfCompositeControl.CallbackResults.Add(errorCallbackResult)
        Else
          m_callbackResultCollection.Add(errorCallbackResult)
        End If
      Else
        ' Since the page is in full postback, write the javascript alert code directly to the response
        Dim jsErrorAlert As String = String.Format("<script>{0}</script>", Utility.GetJavaScriptErrorString(exception))
        Response.Write(jsErrorAlert)
      End If
    End Try
  End Sub

  #End Region

  #Region "Web ADF Control Event Handlers"

  Private Sub MapResourceManager1_ResourcesDispose(ByVal sender As Object, ByVal e As System.EventArgs)
    ' If the target layer has been removed (indicated by the session variable), then we need to add it back to the resource
    ' before the server context created as a result of the current page request is released.  Otherwise, the target layer 
    ' will be missing from the map service outside the scope of this request, so other clients using the service will not have
    ' access to it.
    If (Not Session("LayerRemoved") Is Nothing) AndAlso (CBool(Session("LayerRemoved"))) Then
      ' Get the resource from which the layer was removed
      Dim agsMapFunctionality As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality = CType(Map1.GetFunctionality(m_targetResourceName), ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality)
      Dim mapResourceLocal As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal = CType(agsMapFunctionality.Resource, ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal)

      ' Retrieve a reference to the missing layer and its original layer index from the class-level dictionary that
      ' stored this information when the layer was removed
            Dim removedLayerEnumerator = m_removedLayerDictionary.GetEnumerator()
      removedLayerEnumerator.MoveNext()
      Dim removedGeoFeatureLayer As ESRI.ArcGIS.Carto.IGeoFeatureLayer = TryCast(removedLayerEnumerator.Current.Value, ESRI.ArcGIS.Carto.IGeoFeatureLayer)
      Dim layerIndex As Integer = removedLayerEnumerator.Current.Key

      ' Add the layer back to the map service
      m_serverObjectStateModifier.AddLayer(mapResourceLocal, removedGeoFeatureLayer, layerIndex)
    End If
  End Sub

  #End Region

  #Region "ICallbackEventHandler Members"

  ' Receives the arguments packaged in the callback on the client.  We parse those arguments here and 
  ' initiate server-side logic accordingly.
  Public Sub RaiseCallbackEvent(ByVal eventArgs As String) Implements System.Web.UI.ICallbackEventHandler.RaiseCallbackEvent
    Try
      ' Parse the callback string passed from the client to the server into separate
      ' arguments using the Web ADF's callback parsing utility.
      Dim callbackArgsCollection As System.Collections.Specialized.NameValueCollection = ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackUtility.ParseStringIntoNameValueCollection(eventArgs)

      ' Check whether the callback's event argument
      Select Case callbackArgsCollection("EventArg")
        Case "removeLayer"
          ' Check whether the session variable indicating that the layer has been removed has been populated.  If not, then
          ' the layer is still in the service and needs to be removed.
          If Session("LayerRemoved") Is Nothing Then
            Session("LayerRemoved") = True

            ' Get the layer's target resource and call the method to remove the layer from it
            Dim agsMapFunctionality As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality = CType(Map1.GetFunctionality(m_targetResourceName), ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality)
            Dim mapResourceLocal As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal = CType(agsMapFunctionality.Resource, ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapResourceLocal)

            ' Store a reference to the dictionary containing the layer and its index in the map service
            m_removedLayerDictionary = m_serverObjectStateModifier.RemoveLayer(mapResourceLocal, m_targetLayerName)

            ' Refresh the Map and Toc so they reflect the layer's removal
            RefreshMapAndToc()
          End If
      End Select
    Catch exception As System.Exception
      ' Get a callback result that will alert the user of the error and add it to the callback results collection
      Dim errorCallbackResult As ESRI.ArcGIS.ADF.Web.UI.WebControls.CallbackResult = Utility.GetErrorCallback(exception)
      m_callbackResultCollection.Add(errorCallbackResult)
    End Try
  End Sub

  ' The last server-side method called before the callback returns to the browser, GetCallbackResult
  ' is where the server-side result of the callback is passed back to the browser as a string for
  ' processing by the client.
  Public Function GetCallbackResult() As String Implements System.Web.UI.ICallbackEventHandler.GetCallbackResult
    Return m_callbackResultCollection.ToString()
  End Function

  #End Region

  #Region "Instance Properties"

  ' Property allowing client-side access to the client callback function string.  This string
  ' contains the necessary JavaScript syntax to initiate a callback with the parameters specified
  ' in GetCallbackEventReference (in Page_Load).
  Public Property AdfCallbackFunctionString() As String
    Get
      Return m_adfCallbackFunctionString
    End Get
    Set
      m_adfCallbackFunctionString = Value
    End Set
  End Property

  #End Region

  #Region "Instance Methods"

  ' Refreshes the Map and Toc controls and populates the callback results member variable with the
  ' resulting callback results 
  Private Sub RefreshMapAndToc()
    Toc1.Refresh()
    Map1.CallbackResults.CopyFrom(Toc1.CallbackResults)

    Map1.RefreshResource(m_targetResourceName)
    m_callbackResultCollection.CopyFrom(Map1.CallbackResults)
  End Sub

  #End Region
End Class